Fandom

How To Wiki

ER core assembly exploded.png

1,795pages on
this wiki
Add New Page
Talk0

Ad blocker interference detected!


Wikia is a free-to-use site that makes money from advertising. We have a modified experience for viewers using ad blockers

Wikia is not accessible if you’ve made further modifications. Remove the custom ad blocker rule(s) and the page will load as expected.

Full resolution(1,280 × 960 pixels, file size: 213 KB, MIME type: image/png)

Aquired from http://commons.wikimedia.org/wiki/Image:ER_core_assembly_exploded.png

Summary Edit

Description

exploded view of a ER core-based ferrite inductor

Source Own work
Date

24/06/2006

Author

Cyril BUTTAY

Permission
(Reusing this image)

as licensed

Licensing Edit

I, the copyright holder of this work, hereby publish it under the following licenses:
Heckert GNU logo white

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".

CC some rights reserved
Cc-by new whiteCc-sa white
This file is licensed under the Creative Commons Attribution ShareAlike license versions 3.0, 2.5, 2.0, and 1.0

...

You may select the license of your choice.


made using povray 3.5 and the following source:

#declare RAD = on;   // use radiosity?
#declare Exploded=on; // exploded view or not?
#declare CoilLength = 2.6;

#include "functions.inc"
#include "metals.inc"
#include "colors.inc"
global_settings {
  #if(RAD)
    radiosity {
      brightness 0.60 
      count 100
      error_bound 0.2
      gray_threshold 0.0
      low_error_factor 0.2
      minimum_reuse 0.015
      nearest_count 10
      recursion_limit 1
      #if (version>3.1)
        adc_bailout 0.01
        max_sample -1.0
        media off
        normal off
        always_sample 1
        pretrace_start 0.08
        pretrace_end 0.01
      #end
    }
  #end
}

background { color White }

// declarations for the magnetic core------------------------------------------------
#declare corner = lathe { // a quarter of cyclindic volume used to "round" the corners
    linear_spline
    6
    <0,0>,<0.05,0>, <0.1,0.05>, <0.1,0.95>,<0.05,1>, <0,1>
    rotate 90*x 
}
#declare side =  prism { // the extrusions of the volume
  linear_sweep
  linear_spline
  0, 1, 9,
  <0.05,0>, <0,0.05>, <0,0.95>, <0.05,1>, <0.45,1>, <0.5,0.95>, <0.5,0.05>, <0.45,0>, <0.05,0>
}
#declare bottom = prism { // The bottom of the core
  linear_sweep
  linear_spline
  0, 1, 9,
  <0.25,0>, <0,0.05>, <0,0.95>, <0.25,1>, <0.35,1>, <0.4,0.95>, <0.4,0.05>, <0.35,0>, <0.25,0>
}
#declare middle =  cylinder { // the extrusion of the middle leg
  <0,0,0>,<0,1,0>,0.5
}
#declare core = union {
  difference{
    union{
      object {side scale <1,1.7,1> translate -1.7*x  }
      object {side scale <1,1.7,1> translate 1.2*x  }
    }
    cylinder{<0,-10,0.5>,<0,10,0.5>,1.3 translate 0.3*y}
  }
  object {bottom scale <1,3.2,1> rotate -90*z translate <-1.6,0.3,0> }
  object {corner translate -1.6*x}
  object {corner translate 1.6*x} 
  object {middle scale <1,1.7,1> translate <0,0,0.5>  }
  pigment { Gray50}
}

//declaration of the coil element-------------------------------------------------------- 
#declare coil = isosurface {
  function {f_helix1(x,y,z, 1, 60, 0.05, 1, 1, 1, 0)}
  contained_by { box { -CoilLength/2, CoilLength/2 }}
  pigment { P_Copper4 }
  finish {F_MetalB}//C
}

//declarations for the bobbin-------------------------------------------------------------
declare pin = union {
  box{<0,-0.3,-1>,<0.3,0,0> pigment {Gray20 } 
    translate<-0.15,0,0>
  }
  cylinder{<0,-0.15,-1.5>,<0,-0.15,0>,0.05 
    pigment{ P_Copper4 }
    finish {F_MetalB}
  }
}
#declare bobin_extremity = difference{
  union {
    cylinder{<0,0,0>,<0,0.1,0>,1.15}
    box {<-1.8,-0.3,-0.6>,<1.8,0.1,0.6>}
    prism {
      linear_sweep
      linear_spline
      0, 0.2, 4,
      <1.8,0>,<1.92,0.15>,<-1.92,0.15>,<-1.8,0>
      rotate -90*x
      translate <0,-0.15,0.1>
    } 
    #declare Index = 0.3;
    #while(Index <= 1.7)
      object{pin translate <-Index,0,0>}
      object{pin translate <Index,0,0>}
      #declare Index = Index + 0.6;
    #end
  }
  merge {
    box {<-1.1501,-1,-0.55>,<1.1501,0,0.55>}
    box {<-1.75,-1,-0.55>,<-1.15,1,0.55>}
    box {<1.75,-1,-0.55>,<1.15,1,0.55>}
  }
}
#declare bobbin = difference {
  union {
    cylinder{<0,-0.1,0>,<0,CoilLength+0.1,0>,0.6}
    object{bobin_extremity translate <0,-0.1,0>}
    object{bobin_extremity rotate 180*z translate <0,CoilLength+0.1,0>}
  }
  cylinder{<0,-10,0>,<0,10,0>,0.55 pigment { Gray20 } }
  pigment { Gray20 } 
}

//declarations for the clip
#declare halfclip = difference { 
  prism {
    linear_sweep
    bezier_spline
    0, 1, 32, 
    <0,0>,<1.2,0>,<0,0>,<1.2,0>,
    <1.2,0>,<1.3,0>,<1.6,-0.2>,<1.7,-0.2>,
    <1.7,-0.2>,<1.8,-0.2>,<1.8,-0.2>,<1.8,0.5>,
    <1.8,0.5>,<1.9,0.5>,<1.8,0.5>,<1.9,0.5>,
    <1.9,0.5>,<1.9,-0.3>,<1.9,-0.3>,<1.7,-0.3>,
    <1.7,-0.3>,<1.6,-0.3>,<1.3,-0.1>,<1.2,-0.1>,
    <1.2,-0.1>,<0,-0.1>,<1.2,-0.1>,<0,-0.1>,
    <0,-0.1>,<0,0>,<0,-0.1>,<0,0>
    pigment {P_Chrome1}
    finish {F_MetalC}
  }
  box {<0,0.2,0.25>,<10,0.8,0.4>
    pigment {P_Chrome1}
    finish {F_MetalC}
  }
}
#declare completeclip = union {
  object{halfclip scale 0.5*y}
  object{halfclip scale 0.5*y rotate 180*z translate 0.5*y} 
}

// the final union-------------------------------------------------
union {
  object {bobbin rotate -90*x translate <0,0.5,-0.4>}
  object {coil rotate -90*x translate <0,0.5,-CoilLength/2-0.4>}
  object {core rotate -90*x translate <0,0,0>}
  #if(Exploded)  
    object {core rotate 90*x translate <0,1,-6.5>} 
    object {completeclip translate <0,0.25,-8>}
  #else
    object {core rotate 90*x translate <0,1,-3.4>} 
    object {completeclip translate <0,0.25,-3.5>}
  #end
  object {completeclip rotate 180*y  translate <0,0.25,0.1>}
  rotate <0, 30, 0>
  finish {
    #if(RAD)  
      ambient 0
      diffuse 0.7 
    #else
      ambient 0.8 
      diffuse 0.5      
    #end   
    phong 1
    phong_size 60
  } 
}
light_source { <0, 14, -10> color White}
light_source { <2, 4, -10> color White}
#if(Exploded)  
  camera {location <1,10,-15> look_at <-3.3,-3.5> angle 33}
#else
  camera {location <1,10,-15> look_at <-1.25,-1,0> angle 20}
#end
<pre>

And then compiled using the following command:
<pre>
povray -IER_core_assembly_exploded.pov +a -Q11 -W1280 -H960

Appears on these pages
of

See full list >

File history

Click on a date/time to view the file as it appeared at that time.

Date/TimeThumbnailDimensionsUserComment
current04:48, February 16, 2008Thumbnail for version as of 04:48, February 16, 20081,280 × 960 (213 KB)ZyMOS (Talk | contribs)== Summary == {{Information |Description=exploded view of a ER core-based ferrite inductor |Source=Own work |Date=24/06/2006 |Author=Cyril BUTTAY |Permission=as licensed |other_versions= }} == Licensing == {{self2|GFDL|cc-by-sa-2.5,2.0,1.0}} made